***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 15, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD14P06A-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2   205u TC=3m
Rg     g1    g2     22.65
M1     d2     g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS PMOS ( KP=17   VTO=-2.4  THETA=0  VMAX=1.2e5  ETA=0.003  LEVEL=3  GAMMA=0.95  )
Rd     d1    d2    74m TC=6m,7u
Dbd    d2    s2    Dbt
.MODEL     Dbt    D(BV=66  TBV1=4.895e-4   M=6.269e-1  CJO=9.258e-11  VJ=8.175e-1)
Dbody   21   s2    DBODY
.MODEL DBODY  D(IS=7.739e-12    N=8.8451e-1  RS=12.04u  EG=1.1  TT=30n ikf=6.7961e-4)
Rdiode  d1  21    1.4244e-2  TC=0.5m
.MODEL   sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.415e-10
.MODEL     DGD    D(M=3.245e-1  CJO=1.415e-10   VJ=5.041e-1)
Rpar      b    d2   1Meg
Dgd       d2    a   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    7.99667e-10
.ENDS
*$
